Статья Циклические операции и примеры (команда FOR)

Тема в разделе "Пакетные файлы CMD, BAT", создана пользователем Dragokas, 28 июн 2016.

  1. Dragokas
    Оффлайн

    Dragokas Very kind Developer Команда форума Супер-Модератор Разработчик Клуб переводчиков

    Сообщения:
    4.492
    Симпатии:
    4.309
    Циклическиe операции FOR

    Командой FOR задаётся список команд, которые выполняются с КАЖДЫМ элементом набора.
    Набор* пишется внутри IN (...)
    Список команд пишется внутри DO (...)
    Командная строка выполняет эти команды раз за разом, при этом текущий элемент набора находится в переменной, заданной после %% (назовём ее переменной цикла).

    Например,
    Код (Text):

    FOR %%a IN (C:\Users\*.txt) DO echo %%a
     
    выведет имена и путь ко всем файлам с расширением .txt в папке C:\Users.

    * Примеры под спойлером
    Для команды For без ключей набором может являться:

    1) Маска файлов* (или путь + маска файлов)
    - в двойных кавычках, или без них:

    IN (*.txt)
    Результат: список файлов с расширением .txt в текущем каталоге.

    IN (*.txt *.bat)
    Результат: список файлов с расширениеми .txt и .bat в текущем каталоге.

    IN ("C:\Folder 1\Doc_31-12-*.txt")
    Результат: тот же. Но поиск ведется в каталоге C:\Folder 1 (заметьте с пробелом в имени);
    имя файла начинается на Doc_31-12-

    Прим.: FOR без ключа не умеет выводить список каталогов.
    * маска файлов - это набор файлов, заданный с помощью подстановочных знаков * и/или ?
    где * - обозначает 0 или больше любых символов в имени файла.
    а ? - означает 0 или 1 любой символ в имени файла.

    2) Строка
    - в двойных кавычках, или без них:

    Строкой считается любая последовательность символов, если она не содержит знаков маски * или ?
    Смысл цикла здесь в том, чтобы разбить такую строку по пробелам (или знакам табуляции)
    и выполнить с каждой подстрокой список команд.
    Код (Text):

    FOR %%a IN (гитара рыбка) do echo Моя %%a
     
    Результат:
    Если мы хотим, чтобы какая-то из строк не "билась" по пробелам, укажем ее в двойных кавычках:
    Код (Text):

    FOR %%a IN (гитара "дорогая рыбка") do echo Моя %%~a
     
    Результат:
    При этом, чтобы не выводились сами кавычки "" мы используем модификатор* ~ (тильда) при раскрытии переменной цикла %%~a

    *О других модификаторах переменной цикла можно почитать здесь и здесь.

    3) еще есть смешанный тип. Это когда в наборе стоит маска (1-й описанный тип), а через пробел Строка (2 тип)... ведет себя вполне ожидаемо, но вряд ли найдет себе применение.

    О наборах для FOR с ключем /F далее в нижнем спойлере.

    Ключ /F часто используется для построчного разбора файла, т.е.
    Код (Text):

    FOR /f "usebackq delims=" %%a IN ("C:\1.txt") DO echo %%a
     
    выведет все строки файла 1.txt, который находится в корне диска C.

    UseBackQ (Use back quotes) означает, что набор с двойными кавычками* подразумевает передачу в цикл имени файла.
    delims= означает, что в переменную %%a будет записана вся строка (без разделения по пробелу или знаку табуляции, т.к. стандартный разделитель заменен на NULL (пустой символ).
    В такой вариации:
    tokens=* приводит к тому же результату, что и delims=. Означает прекратить разбивку по разделителю после "0-го" токена, т.е. сразу же.

    * Этот вариант необходим для работы с файлом, путь или имя которого содержит пробелы.
    Можно было не использовать UseBackQ, тогда команда приняла бы вид:
    Код (Text):

    FOR /f "tokens=" %%a IN (C:\1.txt) DO echo %%a
     
    но такая конструкция восприняла бы пробел в имени как определение нового файла, поэтому UseBackQ более приемлем.

    ** Примеры под спойлером
    В цикле FOR /F вид задаваемого набора зависит от формы кавычек в IN (...), а также наличия ключевого слова UseBackQ

    Виды наборов для FOR /F:
    1) Набор файлов (задание маски недопустимо!)

    без UseBackQ - задается без кавычек IN (...)
    __с UseBackQ - может задаваться как в кавычках так и без них. IN (...) IN ("...")

    Функционал: чтение содержимого файла(ов) построчно в переменную цикла!

    Принцип работы: источником для разбиения по разделителю (delims) является содержимое файла, заданного внутри IN (...) или файлов, если они заданы через пробел.

    Исключение: принятый по-умолчанию разделитель (пробел и знак табуляции) для этой конструкции цикла не применяется.

    А что получится, если установить delims= (возле равно - знак пробела) ?
    Код (Text):

    FOR /F "delims= " %%a in (1.txt) do echo %%a
     
    В выводе на экран командой Echo %%a мы получим содержимое файла, где каждая из строк будет напечатана до первого встретившегося пробела.

    2) Строка (допускаются практически любые символы)

    без UseBackQ - задается с двойными кавычками IN ("...")
    __с UseBackQ - задается с одиночными прямыми кавычками IN ('...')

    3) Команда (сначала выполняется она, а уже ее результаты обрабатываются циклом как строка(-и))

    без UseBackQ - задается с одиночными прямыми кавычками IN ('...')
    __с UseBackQ - задается с одиночными обратными кавычками IN (`...`)

    Примеры:

    1.1. Чтение файла - Набор файлов
    Код (Text):

    FOR /F %%a IN (c:\users\1.txt c:\users\2.txt) do echo.%%a
     
    Результат: выведет подряд содержимое двух файлов - 1.txt и 2.txt из каталога c:\users
    Прим.: Echo. - с точкой - это обход ошибки, чтобы можно было напечатать пустую строку, точнее строку с пробелами.

    1.2. Чтение файла - Набор файлов + UseBackQ
    Получаем возможность использовать пробелы.
    Код (Text):

    FOR /F "usebackq" %%a IN ("c:\folder 1\1.txt") do echo.%%a
     
    Результат: выведет содержимое файла 1.txt из каталога c:\folder 1
    (заметьте, в имени папки есть пробел).

    2.1. Строка
    Код (Text):

    FOR /F %%a in ("Каждое слово в отдельную переменную") echo a=%%a; b=%%b; c=%%c; d=%%d; e=%%e
     
    2.2. Строка + UseBackQ
    Код (Text):

    FOR /F "UseBackQ" %%a in ('Каждое слово в отдельную переменную') echo a=%%a; b=%%b; c=%%c; d=%%d; e=%%e
     
    Результат такой же.

    3.1. Команда
    Код (Text):

    For /F "tokens=1-4" %%a IN ('Dir /A:D-L') Do Echo Папка %%d Дата модификации %%a. Время %%b
     
    Сначала выполняется Dir /AD-L, которая выводит информацию о папках в текущем каталоге.
    Вот что попадает под разбор циклу:

    [​IMG]

    Далее цикл разбирает каждую строку по пробелам и табуляции на подстроки (токены).
    На примере 1-й строки:
    1-й токен (%%a)=29.12.2012 ...2-й токен (%%b)=15:16 ...3-й токен (%%c)=<DIR> ...4-й токен (%%d)=Favorites
    ...
    Результат через Echo выводится на экран:
    3.2. Команда + UseBackQ
    Код (Text):

    For /F "Usebackq tokens=1-4" %%a IN (`Dir /A:D-L`) Do Echo Папка %%d Дата модификации %%a. Время %%b
     
    Результат такой же.
    Альтернативный вариант нужен с целью, если одна из выполняемых команд требует точно такие же кавычки как и ключевое слово IN (...).
    Дабы не пользоваться символом экранирования, просто применяем другие кавычки.

    Отличительной особенностью FOR /F является умение работать через токены*,
    а также поддержка дополнительных ключевых слов:
    1) eol - знак комментария в начале строки (1-й символ). Т.е. строки с таким символом не будут обрабатываться. (по умолчанию, знак точки с запятой ; )
    2) skip - пропуск определенного кол-ва обрабатываемых строк от начала файла
    3) delims - задать другой разделитель(-ли) (по умолчанию, пробел и знак табуляции)
    4) tokens - количество получаемых токенов (подстрок) в теле цикла и пределы разбивки по разделителю.
    Также можно задать конкретный № токена, который попадет в первую переменную цикла.
    5) usebackq - изменение правил использования кавычек внутри IN (...)

    Детальную справку можно получить, введя в консоль команду FOR /?

    * Токены - это подстроки, которые попадают в переменные цикла %% в каждой из итераций.
    Они получаются в результате разбивки строки, заданной в IN (...), по разделителю, заданному в Delims= (по умолчанию, пробел и знак табуляции).

    В отличие, от FOR без ключа, в FOR /F все токены (все подстроки одной строки) попадают сразу В ПЕРВУЮ ИТЕРАЦИЮ цикла.
    Они будут распределены по РАЗНЫМ переменным цикла, идущим в алфавитном порядке*, начиная с буквы, заданной после FOR /F %%

    Т.е.
    Код (Text):

    FOR /F %%a IN ("гитара рыбка") do echo Моя %%a и моя %%b.
     
    Результат:
    *
    Максимальное кол-во токенов составляет - 26,
    если начальным указать %%a либо %%A (регистр имеет значение)
    При этом переход с %%z в %%A не происходит. Остальная часть подстрок опускается.
    Можно проверить:
    Код (Text):

    For /F "tokens=1,2" %%z IN ("1 2") do echo %%A
     
    Бывают случаи, когда требуется разбить строку по специфическому разделителю и при этом выполнить одну и ту же команду над каждой из подстрок (токеном). Кол-во токенов неизвестно.
    Метод показал Anonymоus в теме Символ переноса строки в переменной окружения

    Алгоритм заключается в замене разделителя на пробел с одновременным заключением каждого токена в двойные кавычки. Далее строка разбирается обычным циклом FOR без ключа.

    Более универсальные конструкции на основе FOR /F для работы с файлами/папками строятся путем помещения
    в IN ('...') команды, результаты от выполнения которой уж затем обрабатываются циклом.
    Чаще всего это команда Dir.

    1.2. Чтение файла (сложный пример).
    Давайте возьмем сложный пример, и раскусим "крепкий орешек" [​IMG]
    Код (Text):

    FOR /F "UseBackQ skip=1 tokens=2 delims=/\ eol=" %%X in ("%~dp01.txt") do echo %%X
     
    Имеем в распоряжении файл 1.txt, который находится рядом с батником.

    Порядок разбора (или "как прибл. будет думать ком. строка"):

    1) %~dp0 - означает каталог, где находится батник, например c:\temp\

    2) UseBackQ, ага - значит если в IN (...) ничего нет или двойные кавычки, то это файл и его нужно прочесть.

    3) Читаем содержимое файла 1.txt в папке %~dp0, а затем каждую его строку проверяем по правилам... ключевых слов skip=1 tokens=2 delims=/\ eol=

    4) Итак, первая строка так и называется "первая строка" [​IMG]
    skip=1 - означает пропустить от начала файла 1-у строку,
    значит идем дальше:

    5) Вторая строка: ";комментарий/кода"
    Первый символ - это точка с запятой. А теперь смотрим сюда "eol=пустой символ".
    По умолчанию eol=; и если бы мы не указали пустой EOL, то цикл просто бы пропустил эту строку.
    Итак, символ комментария не совпадает с заданным (т.е. он вообще пустой), а значит строчка нам подходит -> проверяем ее дальше:

    6) Смотрим какие приняты разделители: delims=/\ (знаки / и \ ), значит
    из строки ";комментарий/кода"
    мы получим 2 подстроки:
    1-й токен - ";комментарий"
    2-й токен - "кода"

    7) Теперь смотрим сюда tokens=2 - значит, что первой букве цикла нужно присвоить значение 2-го токена.
    Первая буква цикла у нас X. Переменная называется %%X
    А второй токен - это подстрока "кода"

    8) Только теперь мы попадаем в тело цикла: Echo %%X
    что означает - вывести на экран текст "кода"

    С 3-ей строкой потренируйтесь самостоятельно.
    кода
    блюдо

    Ключ /L

    Код (Text):

    FOR /L %%a IN (0,2,6) DO echo %%a
     
    IN (первое, шаг, последнее)
    означает математическое перечисление чисел от первого числа (0), до третьего (6), с шагом, указанным вторым числом (2) в наборе IN (...).

    Указанная команда выведет:

    Прим.: дробные числа командной строкой не поддерживаются.
     
  2. Dragokas
    Оффлайн

    Dragokas Very kind Developer Команда форума Супер-Модератор Разработчик Клуб переводчиков

    Сообщения:
    4.492
    Симпатии:
    4.309
    Продолжение...

    Особенности, которые распространяются на циклы FOR

    0) Если нужно записать в наборе несколько команд, то используем:

    а) знаки амперсанда &, если мы хотим записать все в одну строку:
    Код (Text):

    FOR /L %%a IN (1,1,10) DO echo Найден файл:& echo %%a
     
    б) знаки скобок, если хотим разбить команды в несколько строк для наглядности и удобства:
    Код (Text):

    FOR /L %%a IN (1,1,10) DO (
      echo Найден файл:
      echo %%a
    )
     
    1) Пустые строки в содержимом файлов и выводе команд игнорируются.

    2) Если предполагается получение пустого токена, остальные токены смещаются.
    К примеру,
    имеем файл с содержимым:
    Применим команду:
    Код (Text):

    FOR /F "tokens=1,2,3 delims=/" %%a in (file.txt) do echo a=%%a; b=%%b; c=%%c
     
    Результат будет:
    вместо ожидаемого
    3) Все специальные (служебные) символы необходимо экранировать (предварять птичкой ^).
    Это такие символы, как | = ^ < > &. А также % ! - если они используются не для раскрытия переменной, кроме случая с !, когда не включено удаленное расширение переменных.
    Сюда же входит знак кавычки, которая соответствует форме кавычки, применяемой для определения вида набора.

    4) Регистр переменной цикла имеет значение.

    5) Изменить вручную значение переменной цикла нельзя. Например, set %%A=param не даст эффекта.

    6) После выхода из цикла переменная цикла уничтожается.

    7) Внутри цикла можно использовать не более 1-го комментария вида :: (иначе, будет критическая ошибка и "вылет" из пакетного файла)
    Вместо этого используем Rem.

    8) Внутри цикла можно использовать не более 1-й метки (иначе, будет такой же "вылет").

    Пример максимально допустимой конструкции:
    Код (Text):

    @echo off
    for %%n in ( 0 1 2 3 4 5 6 7 8 9 ) do (
        :label
        echo %%n
        :: comment
        echo %%n
    )
     
    9) Тем не менее из цикла можно безвозвратно выйти на метку Goto metka
    а также выйти в подпрограмму и вернутся снова в цикл точно в ту же позицию через команду Call :metka
    В конце подпрограммы должна стоять команда Exit /B

    10) Для получения значения обычной переменной внутри цикла в случае, если этой переменной было присвоено новое значение внутри тела этого же цикла, необходимо раскрывать переменную через знаки восклицания !variant! - это называется отложенное расширение переменных.
    Перед использованием такого способа, его нужно включить, задав в начале пакетного файла команду:
    Код (Text):

    SetLocal EnableDelayedExpansion
     
    Иначе, если использовать обычный способ раскрытия %variant%, мы получим значение переменной, присвоенное ей еще до входа в цикл.
    Точно таким же образом (через ! ) необходимо раскрывать переменную времени внутри цикла, т.к. иначе для цикла время "замерзает".
    Происходит это потому, что в цикл попадает т.н. "слепок" переменных среды. И работа с ними через % происходит уже как с копией данных, а не актуальными значениями.

    11) Когда после IN указана команда, под разбор цикла попадают такие потоки:
    1-й поток (StdOut)
    с 3-го по 9-й поток (User Stream)

    При этом 2-й поток (StdError) отображается на экране сразу после выполнения указанной в цикле команды в IN (...)
    2-й поток можно занулить, обычным способом, не забыв экран:
    Код (Text):

    FOR /F %%A IN ('dir %someparam% 2^>nul') do rem
     
    Также можно перенаправить 2-й поток, чтобы он обрабатывался вместе с первым, вместо его вывода на экран:
    Код (Text):

    FOR /F %%A IN ('dir %someparam% 2^>^&1') do rem
     
    Собственно, чтобы наоборот, обрабатывать 2-й поток вместо первого, можно воспользоваться следующей конструкцией:
    Код (Text):

    FOR /F %%A IN ('dir %someparam% 1^>nul 2^>^&3') do rem
     
    12) При запуске цикла из консоли (cmd.exe) переменные цикла нужно указывать без удвоения знака процента %a.
    Это же правило касается вызова цикла через Shell-подобные команды на других языках программирования.

    13) Переменную цикла нельзя раскрыть внутри строки модификаторов другого цикла:
    но есть способ обхода от ComSpec:
    Как известно, значение переменной цикла нельзя просто подставить в качестве модификатора в другой, вложенный, цикл:
    Код (Text):

    for /f "tokens=2" %i in ("1 3 5") do @for /f "tokens=%i" %j in ("1 3 5 7 9") do @echo %j

    Результатом такой подстановки будет вывод ошибки:
    [quote]
    Непредвиденное появление: %i".
    [/quote]

    Если же сделать так:
    [code]
    for /f "tokens=2" %i in ("1 3 5") do @set x=%i
    for /f "tokens=%x%" %j in ("1 3 5 7 9") do @echo %j
     
    то ошибки не будет:
    Но как всё же осуществить корректный вывод во вложенном цикле?

    Если попробовать присвоить какой-нибудь переменной значение переменной первого цикла, а эатем запустить второй цикл с этой переменной в новом экземпляре интерпретатора с включённым отложенным расширением, то ошибка не исчезает:
    Код (Text):

    for /f "tokens=2" %i in ("1 3 5") do @set x=%i& cmd/v/c for /f "tokens=!x!" %j in ("1 3 5 7 9") do @echo %j
     
    результат:
    Оказалось, что это можно сделать проще, а именно просто запустить вложенный цикл в новом экземпляре интерпретатора:
    Код (Text):

    for /f "tokens=2" %i in ("1 3 5") do @cmd/c for /f "tokens=%i" %j in ("1 3 5 7 9") do @echo %j
     
    результат:
     
    Последнее редактирование: 28 июн 2016
  3. Dragokas
    Оффлайн

    Dragokas Very kind Developer Команда форума Супер-Модератор Разработчик Клуб переводчиков

    Сообщения:
    4.492
    Симпатии:
    4.309
    Продолжение...

    Практические примеры:

    1) Использование ключа /D

    (спасибо sov44) Переименовать файл в имя папки

    2) первый по алфавиту файл
    Код (Text):

    for /F %%i in ("*.txt") do set FILE_NAME=%%~nxi
     
    Берет первый по алфавиту файл, заданный маской *.txt, и сразу выходит из цикла.
    Можно также задавать конкретный путь перед маской.
    (спасибо pistol за найденный пример.)

    3) Использование модификатора %~$ПУТЬ:I для поиска файла в папках, заданных переменной среды Path:
    Код (Text):

    for %%a in ("wmic.exe") do echo %%~s$PATH:a
     
    где:
    wmic.exe - наш искомый файл

    4) Разбивка текста по разделителям
    Код (Text):

    for %%i in (text) do echo %%i
     
    где text - текст, разбивка на итерации которого происходит по знакам:
    • пробел
    • парные кавычки *
    • табуляция
    • запятая
    • точка с запятой
    • знак равенства.

    * Примечание от ComSpec:
    5) Удаление лидирующих нулей

    Код (DOS):
    :: математические операции со значениями 08 и 09 будут приводить к ошибкам
    set /a m=%date:~3,2%
    :: поэтому для начала, удаляем лидирующие нули
    set m=%date:~3,2%
    for /f "tokens=* delims=0" %%j in ("%m%") do set m=%%j
    echo %m%
    Дополнение от Smitis:

    Если количество цифр в числе, в котором надо удалить лидирующие нули, известно заранее, то можно поступить так (для месяца из двух цифр)
    Код (DOS):

    :: В вычитаемом числе должно быть столько нулей, сколько цифр исходном числе.

    :: Исходное число должно быть не длинее 9-ти разрядов.
    set /a m=1%date:~3,2%-100
    echo %m%
     
    Можно сразу подставлять такую конструкцию в нужное выражение.

    6) Распределение итераций цикла for без ключей.
    Дополнение: Получение пустых значений токенов в цикле с командой FOR

    7) Использование кавычки в роле разделителя
    Автор: amel27
    Код (Text):
    for /f tokens^=1^,2^,3^ delims^=^" %%a in ("1""2""3") do echo %%a--%%b--%%с
    8) Циклическая конструкция с использованием сочетания модификаторов
    (от ComSpec)

    "tokens=* delims=<символы>"
    является универсальным "триммером" для удаления любых заявленных символов из начала строки до первого незаявленного символа.

    Пример:
    Код (Text):

    for /f "tokens=* delims=0123456789" %i in ("972630014380333075vfh658weghui72qcfgb3658eyfgcb7652qweuy8") do @echo %i
     
    результат:
    9) получение результата выполнения программы в переменную
    (если результатат - 1 строка)
    Код (Text):
    for /f "delims= eol=" %%a in ('file.exe') do set "var=%%a"
     
    Последнее редактирование: 28 июн 2016

Поделиться этой страницей