[CMD] Слияние нескольких текстовых файлов в один

[monowar]

Есть несколько текстовых файлов - нужно перенести их содержимое (текст) в один файл.
Есть батник

@Echo Off
@chcp 1251
for %%i in ("*.txt") do >>"%%i" echo:
copy /a "*.txt" "some.tmp" && ren "some.tmp" "some.txt"
exit

Но он даёт такой результат

Спойлер: Скрин

А надо такой

Спойлер: Скрин

или

Можно-ли батник доработать ?

 

[Dragokas]

Пример файлов дайте (в виде прикрепленного файла).

И в какой кодировке нужно на выходе получить?

 

[monowar]

@Dragokas, если я правильно тебя понял , то с этими файлами работал батник

А кодировку можно ASHI или UTF-8

 

[Dragokas]

Технически твой батник выполняет все, как описано - соединяет содержимое.
Ты хочешь удалить пустые строчки, как я понимаю?
Каков примерный объём (в кол-ве строк) реальных данных?

 

[Dragokas]

Вообщем-то такой алгоритм должен быть быстрым:

@echo off
Setlocal EnableExtensions
md result 2>NUL
set res=result\result.txt
del "%res%" 2>NUL
for %%i in ("*.txt") do (
  < %%i findstr /VR "^$" >> "%res%"
  echo --------------->> "%res%"
)
pause

Результат в подпапке result.

 

[monowar]

Ты хочешь удалить пустые строчки, как я понимаю?

Да именно это я и хочу , а объём - разный (дурная привычка создавать много текстовых файлов)

Батник работает (соединяет без пустых строк) ,но соединяет всего два файла, запускаю в папке с файлами

Ещё есть батник ,но он только для двух файлов ,попробовал его - два раза соединил без пустых строк , а потом начал соединять с пустыми строками.

@Echo Off
@chcp 1251
(
    type 1.txt
    echo:
    type 2.txt
)>final.txt
exit

Может ОСь начала голову кружить?

 

[Dragokas]

Батник работает (соединяет без пустых строк) ,но соединяет всего два файла, запускаю в папке с файлами

ты про батник на основе findstr?
А он точно доработал до конца (и не завис)?

 

[monowar]

доработал до конца (и не завис)?

Cоздал папку>текстовой файл >соединил два файла txt и пустая консоль cmd открылась

 

[Dragokas]

Понятно, значит Microsoft так и не починила эту утилиту.

Можете попробовать построчный разбор, но это медленно:

@echo off
Setlocal EnableExtensions
md result 2>NUL
set res=result\result.txt
del "%res%" 2>NUL
for %%i in ("*.txt") do (
  for /f "usebackq delims=" %%a in ("%%~i") do echo >> "%res%" %%a
  echo --------------->> "%res%"
)
pause

Если данных очень много, нужно писать на другом ЯП.

 

[monowar]

@Dragokas, Спасибо! Нет не медленно, 5 файлов по 5-8 Kb моментально. Вот этот параметр "usebackq delims=" убирает пустые строчки? Я пытался вставить " delims=" ,но у меня ничего не получалось и 2>NUL -что это даёт (вкратце)

 

[Dragokas]

Нет, for "из коробки" убирает пустые строчки

 

[fils]

А чем Вас не устраивает батник в одну строчку[:

copy ABC abc.txt

В папке ABC должны находятся все txt файлы (например, a.txt, b.txt, c.txt), тексты которых надо объединить в abc.txt файле. Батник, в данном случае, должен находиться рядом с папкой. Если же прописать полный адрес папки, тогда где угодно.

 

[fils]

С раделительной чертой:

for /r ABC %%a in (*) do (
type %%a>>abc.txt
echo.---------------------------->>abc.txt
)

 

[Dragokas]

@fils, ему нужно удалить пустые строки (см. скрин).
И ей богу, пользуйтесь тегами [ CODE ]

 

[fils]

Пустые строки можно убрать так:

for /r ABC %%a in (*) do for /f "usebackq delims=" %%b in (%%a) do echo.%%b>>abc.txt

 

[fils]

Без пустых строк и с чертой

for /r ABC %%a in (*) do (
for /f "usebackq delims=" %%b in (%%a) do (
echo.%%b>>abc.txt
)
echo.---------------------------->>abc.txt
)

так:

 

[fils]

Можно и так (без пустых строк и черты):

copy ABC xyz.txt
for /f "usebackq delims=" %%a in (xyz.txt) do echo.%%a>>abc.txt
del /q xyz.txt

 

[monowar]

@fils, Твой тоже вариант рабочий .
А ещё можно-ли этот батник доработать , чтобы вид был такой черта - название файла - черта (а дальше содержание файла до следующей черты) ?

 

[fils]

Попробуй это.

for /r ABC %%a in (*) do (
echo.---------------------------->>abc.txt
echo.      %%~nxa>>abc.txt
echo.---------------------------->>abc.txt
for /f "usebackq delims=" %%b in ("%%~a") do (
echo.%%b >>abc.txt
)
)

 

[fils]

@fils, Твой тоже вариант рабочий .
А ещё можно-ли этот батник доработать , чтобы вид был такой черта - название файла - черта (а дальше содержание файла до следующей черты) ?

for /r ABC %%a in (*) do (
echo.---------------------------->>abc.txt
echo.      %%~nxa>>abc.txt
echo.---------------------------->>abc.txt
for /f "usebackq delims=" %%b in ("%%~a") do (
echo.%%b >>abc.txt
)
)