[CMD] Удалить текст (весь) после знака "." и добавить после точки (m3u8)

[oshiu]

В скрипте использую утилиту для быстрой копипасты.

Изначально ссылка выглядит таким образом: http//***********.flv*****************
Нужно что бы в итоге ссылка принимала такой вид: http//***********.m3u8

clipaste.exe > clipaste
set /p url= < clipaste
del clipaste
start %url%
exit

 

[Dragokas]

Здравствуйте!
Добро пожаловать на SafeZone.

@echo off
set url=http//***********.flv*****************
for /f "delims=. tokens=1" %%a in ("%url%") do set "url=%%a.m3u8"
echo "%url%"
pause

 

[oshiu]

Здравствуйте!
Добро пожаловать на SafeZone.

@echo off
set url=http//***********.flv*****************
for /f "delims=. tokens=1" %%a in ("%url%") do set "url=%%a.m3u8"
echo "%url%"
pause

прошу прощения а если вот такая ссылка? http//**.*****.****.flv***************** забыл указать что точки всего 3

 

[Dragokas]

@echo off
set url=http//***********.flv******1.******2.3*****
set "ret=" & set "last="
if "%url:~-1%"=="." set "url=%url% "
:loop
for /f "delims=. tokens=1*" %%a in ("%url%") do (
    set "url=%%b"
    set "ret=%ret%.%last%"
    set "last=%%a"
    if "%%b" neq "" goto loop
)
set "url=%ret:~2%.m3u8"
echo "%url%"
pause

 

[oshiu]

Спасибо огромное! Все работает как часы)

 

[fils]

Здесь файл aa.txt содержит строки такого типа: http//***********.flv*****************, а файл bb.txt должен быть типа: http//***********.m3u8

for /f "usebackq delims=" %%a in (aa.txt) do (
set x=%%~xa
set y=%%a
call :m1
)
exit
:m1
call set y=%%y:%x%=.m3u8%%
echo.%y%>>bb.txt
goto :eof